;;; SPDX-FileCopyrightText: 2025 Evgeny Pisemsky <mail@pisemsky.site>

;;;

;;; SPDX-License-Identifier: GPL-3.0-or-later

(define-module (cogd packages hardware))

(use-modules (guix packages)

             (guix gexp)

             (guix build-system python)

             ((gnu packages hardware) #:prefix guix:)

             (gnu packages messaging))

(define-public python-usbrelay

  (package

    (inherit guix:usbrelay)

    (name "python-usbrelay")

    (build-system python-build-system)

    (inputs (list guix:usbrelay))

    (propagated-inputs (list python-paho-mqtt))

    (arguments

     (list

      #:phases #~(modify-phases %standard-phases

                   (add-after 'unpack 'install-daemon

                     (lambda _

                       (install-file "usbrelayd.8"

                                     (string-append #$output "/share/man/man8"))

                       (install-file "usbrelayd"

                                     (string-append #$output "/sbin"))

                       (chmod (string-append #$output "/sbin/usbrelayd") #o555)))

                   (add-after 'install-daemon 'chdir-and-set-version

                     (lambda _

                       (chdir "usbrelay_py")

                       (substitute* "setup.py"

                         (("    version = .*")

                          (string-append "    version = '"

                                         #$(package-version guix:usbrelay) "',\n")))

                       (substitute* "src/__init__.py"

                         (("__version__ = .*")

                          (string-append "__version__ = \""

                                         #$(package-version guix:usbrelay) "\"\n"))))))))))