(use-modules (guix records)

             (guix gexp)

             (gnu packages messaging)

             (gnu packages admin)

             (gnu system shadow)

             (gnu services)

             (gnu services shepherd))

(export mosquitto-configuration

        mosquitto-configuration?

        mosquitto-configuration-package

        mosquitto-configuration-config-file

        mosquitto-configuration-user

        mosquitto-configuration-group

        mosquitto-service-type)

(define-record-type* <mosquitto-configuration>

  mosquitto-configuration

  make-mosquitto-configuration

  mosquitto-configuration?

  (package     mosquitto-configuration-package

               (default mosquitto))

  (config-file mosquitto-configuration-config-file

               (default #f))

  (user        mosquitto-configuration-user

               (default "mosquitto"))

  (group       mosquitto-configuration-group

               (default "mosquitto")))

(define (mosquitto-accounts config)

  (match-record config <mosquitto-configuration>

                (user group)

    (filter identity

            (list

             (and (equal? group "mosquitto")

                  (user-group

                   (name "mosquitto")

                   (system? #t)))

             (and (equal? user "mosquitto")

                  (user-account

                   (name "mosquitto")

                   (group group)

                   (system? #t)

                   (comment "bzzz")

                   (home-directory "/var/empty")

                   (shell (file-append shadow "/sbin/nologin"))))))))

(define (mosquitto-shepherd-service config)

  (match-record config <mosquitto-configuration>

                (package config-file user group)

    (list (shepherd-service

           (documentation "Run the mosquitto MQTT broker.")

           (provision '(mosquitto))

           (requirement '(networking syslogd user-processes))

           (start #~(make-forkexec-constructor

                     (list #$(file-append package "/sbin/mosquitto")

                           #$@(if config-file

                                  (list "-c" config-file)

                                  '()))

                     #:user #$user

                     #:group #$group))

           (stop #~(make-kill-destructor))))))

(define mosquitto-service-type

  (service-type

   (description "Run the mosquitto MQTT broker.")

   (name 'mosquitto)

   (extensions

    (list (service-extension account-service-type mosquitto-accounts)

          (service-extension shepherd-root-service-type mosquitto-shepherd-service)))

   (default-value (mosquitto-configuration))))